【Word VBA】市松模様描画マクロ其の二▽ソースコード

Option Explicit

Option Base 0

'

Public Sub 市松模様描画マクロ其の二()

    Const GRIDLEFT = 100　　　　　　        '描画開始位置Ｘ

    Const GRIDTOPP = 80　　　　　　　      '　　　　　　Ｙ

    '

    Const GRIDSWID = 20　　　　　　         '描画幅

    Const GRIDSHEI = 20　　　　　　　       '描画高さ

    '

    Const GRIDCOLS = 10　　　　　　         '横/描画数

    Const GRIDROWS = 8 　　　　　　　　　'縦/描画数

    '---------------------------------------------------------------------------

    Dim Ip As Integer, Jp As Integer

    Dim intDxp As Integer, intDyp As Integer

    Dim lngCol(1) As Long

    Dim varNam(GRIDCOLS * GRIDROWS - 1) As Variant

    '

    lngCol(0) = vbGreen 　　　　　　　　　　'←塗りつぶし色１

    lngCol(1) = vbBlack 　　　　　　　　　　'←塗りつぶし色２

    For Jp = 0 To GRIDROWS - 1

        intDyp = GRIDTOPP + GRIDSHEI * Jp

        For Ip = 0 To GRIDCOLS - 1

            intDxp = GRIDLEFT + GRIDSWID * Ip

            '

            With ActiveDocument.Shapes.AddShape( _

                 msoShapeRectangle, _

                 intDxp, intDyp, GRIDSWID, GRIDSHEI)

                .Fill.Visible = True

                .Fill.ForeColor.RGB = lngCol(((Jp Mod 2) + Ip) Mod 2)

                .Line.Visible = False

                varNam(Jp * GRIDCOLS + Ip) = .Name

            End With

        Next Ip

    Next Jp

    ActiveDocument.Shapes.Range(varNam).Group　　　     '←グループ化

End Sub

《蛇足》

　市松模様描画マクロは、今年３月のブログ「格子の図形を描画するマクロ」の中にありますが、それよりも、ちょっとシンプルにしました。